[Tinyos-2-commits] CVS: tinyos-2.x/apps/tests/TestSerial README, NONE, 1.1.4.2 TestSerialP.nc, NONE, 1.3.2.2 TestSerialAppC.nc, 1.1.2.8, 1.1.2.9 TestSerialC.nc, 1.1.2.10, 1.1.2.11

Phil Levis scipio at users.sourceforge.net
Tue Nov 7 15:15:54 PST 2006


Update of /cvsroot/tinyos/tinyos-2.x/apps/tests/TestSerial
In directory sc8-pr-cvs10.sourceforge.net:/tmp/cvs-serv15393/apps/tests/TestSerial

Modified Files:
      Tag: tinyos-2_0_devel-BRANCH
	TestSerialAppC.nc TestSerialC.nc 
Added Files:
      Tag: tinyos-2_0_devel-BRANCH
	README TestSerialP.nc 
Log Message:
Fold changes back in.


--- NEW FILE: README ---
README for TestSerial
Author/Contact: tinyos-help at millennium.berkeley.edu

Description:

TestSerial is a simple application that may be used to test that the
TinyOS java toolchain can communicate with a mote over the serial
port. The java application sends packets to the serial port at 1Hz:
the packet contains an incrementing counter. When the mote application
receives a counter packet, it displays the bottom three bits on its
LEDs. (This application is similar to RadioCountToLeds, except that it
operates over the serial port.) Likewise, the mote also sends packets
to the serial port at 1Hz. Upon reception of a packet, the java
application prints the counter's value to standard out.

Java Application Usage:
  Linux: java TestSerial.class [-comm <packetsource>]
  Windows: java TestSerial [-comm <packetsource>]

  If not specified, the <packetsource> defaults to sf at localhost:9001 or
  to your MOTECOM environment variable (if defined).

Tools:

Known bugs/limitations:

None.


--- NEW FILE: TestSerialP.nc ---
// $Id: TestSerialP.nc,v 1.3.2.2 2006/11/07 23:14:52 scipio Exp $

/*									tab:4
 * "Copyright (c) 2000-2005 The Regents of the University  of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and its
 * documentation for any purpose, without fee, and without written agreement is
 * hereby granted, provided that the above copyright notice, the following
 * two paragraphs and the author appear in all copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
 * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
 * OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
 * CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
 * AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
 * ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
 * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 *
 * Copyright (c) 2002-2003 Intel Corporation
 * All rights reserved.
 *
 * This file is distributed under the terms in the attached INTEL-LICENSE     
 * file. If you do not find these files, copies can be found by writing to
 * Intel Research Berkeley, 2150 Shattuck Avenue, Suite 1300, Berkeley, CA, 
 * 94704.  Attention:  Intel License Inquiry.
 */

/**
 * Application to test that the TinyOS java toolchain can communicate
 * with motes over the serial port. 
 *
 *  @author Gilman Tolle
 *  @author Philip Levis
 *  
 *  @date   Aug 12 2005
 *
 **/

#include "Timer.h"
#include "TestSerial.h"

module TestSerialP {
  uses {
    interface SplitControl as Control;
    interface Leds;
    interface Boot;
    interface Receive;
    interface AMSend;
    interface Timer<TMilli> as MilliTimer;
    interface Packet;
  }
}
implementation {

  message_t packet;

  bool locked = FALSE;
  uint16_t counter = 0;
  
  event void Boot.booted() {
    call Control.start();
  }
  
  event void MilliTimer.fired() {
    counter++;
    if (locked) {
      return;
    }
    else {
      TestSerialMsg* rcm = (TestSerialMsg*)call Packet.getPayload(&packet, NULL);
      if (call Packet.maxPayloadLength() < sizeof(TestSerialMsg)) {
	return;
      }

      rcm->counter = counter;
      if (call AMSend.send(AM_BROADCAST_ADDR, &packet, sizeof(TestSerialMsg)) == SUCCESS) {
	locked = TRUE;
      }
    }
  }

  event message_t* Receive.receive(message_t* bufPtr, 
				   void* payload, uint8_t len) {
    if (len != sizeof(TestSerialMsg)) {return bufPtr;}
    else {
      TestSerialMsg* rcm = (TestSerialMsg*)payload;
      if (rcm->counter & 0x1) {
	call Leds.led0On();
      }
      else {
	call Leds.led0Off();
      }
      if (rcm->counter & 0x2) {
	call Leds.led1On();
      }
      else {
	call Leds.led1Off();
      }
      if (rcm->counter & 0x4) {
	call Leds.led2On();
      }
      else {
	call Leds.led2Off();
      }
      return bufPtr;
    }
  }

  event void AMSend.sendDone(message_t* bufPtr, error_t error) {
    if (&packet == bufPtr) {
      locked = FALSE;
    }
  }

  event void Control.startDone(error_t err) {
    if (err == SUCCESS) {
      call MilliTimer.startPeriodic(1000);
    }
  }
  event void Control.stopDone(error_t err) {}
}









More information about the Tinyos-2-commits mailing list